home *** CD-ROM | disk | FTP | other *** search
/ Revista do CD-ROM 101 / CD-ROM 101.iso / compl / maya5ple / Install_MayaPLE5_English.exe / Maya / Data1.cab / pluginWin.mel < prev    next >
Encoding:
Text File  |  2003-07-17  |  36.1 KB  |  1,319 lines
  1. // Copyright (C) 1997-2002 Alias|Wavefront,
  2. // a division of Silicon Graphics Limited.
  3. //
  4. // The information in this file is provided for the exclusive use of the
  5. // licensees of Alias|Wavefront.  Such users have the right to use, modify,
  6. // and incorporate this code into other products for purposes authorized
  7. // by the Alias|Wavefront license agreement, without fee.
  8. //
  9. // ALIAS|WAVEFRONT DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  10. // INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  11. // EVENT SHALL ALIAS|WAVEFRONT BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  12. // CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  13. // DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  14. // TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  15. // PERFORMANCE OF THIS SOFTWARE.
  16. //
  17. //
  18. //  Alias|Wavefront Script File
  19. //  MODIFY THIS AT YOUR OWN RISK
  20. //
  21. //  Creation Date:   29 July 1996
  22. //
  23. //  Description:
  24. //      This implements the plugin-manager utility window
  25. //
  26. //  Procedures:
  27. //     pluginWin, updatePluginWin, browsePlugin, displayPluginInfo, 
  28. //     loadPluginCallback
  29. //
  30.  
  31. global int $pluginListSize = 0;
  32. global string $pluginNewestFile[];
  33. global int $pluginFileCount[];
  34. global string $defaultPluginBrowseDir = "";
  35.  
  36. /////////////////////////////////////////////////////////////////
  37. // Helper Functions: these are not exported to the application //
  38. /////////////////////////////////////////////////////////////////
  39.  
  40. proc string getDir( string $path ) 
  41. //
  42. //  Procedure Name:
  43. //      getDir
  44. //
  45. //  Description:
  46. //      strips the file name off of a path
  47. //
  48. //  Return Value:
  49. //      the directory name
  50. //    
  51. {
  52.     string $dir = match( "^.*/", $path );
  53.  
  54.     int $sz = size( $dir );
  55.     // Strip off trailing '/'
  56.     //
  57.     if ( ( $sz > 1 ) && ( substring( $dir, $sz, $sz ) == "/" ) ) {
  58.         $dir = substring( $dir, 1, ($sz - 1) );
  59.     } 
  60.     return $dir;
  61. }
  62.  
  63. proc string getFile( string $path ) 
  64. //
  65. //  Procedure Name:
  66. //      getFile
  67. //
  68. //  Description:
  69. //      returns the final file name in a path
  70. //
  71. //  Return Value:
  72. //      the file name
  73. //    
  74. {
  75.     string $file = match( "[^/]*$", $path );
  76.     return $file;
  77. }
  78.  
  79. proc string abbreviatePath( string $path, int $maxLen )
  80. //
  81. //  Procedure Name:
  82. //      abbreviatePath
  83. //
  84. //  Description:
  85. //      takes a path and trims out some of the middle if
  86. //      it is too long.  The middle part that is taken
  87. //      out will be replaced by "..."
  88. //
  89. {
  90.     int $len = size( $path );
  91.     if ( $maxLen < $len ) {
  92.         int $trimSize = ( $maxLen - 3 ) / 2;
  93.         string $newString = ( `substring $path 1 $trimSize` + "..." 
  94.             + `substring $path ( $len - $trimSize + 1 ) $len` );
  95.         return $newString;
  96.     }
  97.     return $path;                          
  98. }
  99.  
  100.  
  101. /////////////////////////////////////////////////////////////
  102. // Plugin List code.  Maintain a list of plugin info using //
  103. // the available single dimensional arrays in MEL          //
  104. /////////////////////////////////////////////////////////////
  105.  
  106. //
  107. //  Procedure Name:
  108. //      pluginListEntry
  109. //
  110. //  Description:
  111. //      gets info about the plugin at the given index
  112. //
  113. //  Return Value:
  114. //      the contents of the given field
  115. //
  116. proc string pluginListEntry( int $index, string $field ) 
  117. {
  118.     global string $pluginManagerList[];
  119.     int $numElements = 4;
  120.     
  121.     if ( $field == "path" ) {
  122.         $name = $pluginManagerList[$numElements * $index]; 
  123.         return $name;
  124.     } else if ( $field == "fileName" ) { 
  125.         $path = $pluginManagerList[$numElements * $index];
  126.         $name = getFile( $path );
  127.         return $name;
  128.     } else if ( $field == "loadedWidget" ) { 
  129.         $name = $pluginManagerList[($numElements * $index) + 1]; 
  130.         return $name;
  131.     } else if ( $field == "autoloadWidget" ) { 
  132.         $name = $pluginManagerList[($numElements * $index) + 2]; 
  133.         return $name;
  134.     } else if ( $field == "infoWidget" ) { 
  135.         $name = $pluginManagerList[($numElements * $index) + 3]; 
  136.         return $name;
  137.     }
  138.     return "";
  139. }
  140.  
  141.  
  142. proc setPluginListEntry( int $index, string $path, string $loadedWiget,
  143.                          string $autoWidget, string $infoWidget )
  144. //
  145. //  Procedure Name:
  146. //      setPluginListEntry
  147. //
  148. //  Description:
  149. //      Set information about the plugin at the given index
  150. //
  151. //  Return Value:
  152. //      none
  153. //    
  154. {
  155.     global string $pluginManagerList[];
  156.     int $numElements = 4;
  157.     
  158.     $pluginManagerList[$numElements * $index] = $path;
  159.     $pluginManagerList[($numElements * $index) + 1] = $loadedWiget;
  160.     $pluginManagerList[($numElements * $index) + 2] = $autoWidget;
  161.     $pluginManagerList[($numElements * $index) + 3] = $infoWidget;
  162. }
  163.  
  164. proc int appendPluginListEntry( string $path, string $loadedWiget,
  165.                                 string $autoWidget, string $infoWidget )
  166. //
  167. //  Procedure Name:
  168. //      appendPluginListEntry
  169. //
  170. //  Description:
  171. //      appends an item to the list of plugins in the UI
  172. //
  173. //  Return Value:
  174. //      in index in the list of the new item
  175. //
  176. {
  177.     global int $pluginListSize;
  178.     int $i = $pluginListSize;
  179.     setPluginListEntry( $i, $path, $loadedWiget, $autoWidget, $infoWidget );
  180.     $pluginListSize++;
  181.     return $i;
  182. }
  183.  
  184. proc int removePluginListEntries (string $path)
  185. //
  186. //  Procedure Name:
  187. //      removePluginListEntries
  188. //
  189. //  Description:
  190. //      Remove all entries associated in the directory given by $path
  191. //
  192. {
  193.     global string $pluginManagerList[];
  194.     global int $pluginListSize;
  195.     int $numElements = 4;
  196.     
  197.     int $i, $j;
  198.     int $numRemoved = 0;
  199.  
  200.     for ($i = 0; $i < $pluginListSize; $i++)
  201.         if (getDir (pluginListEntry ($i, "path")) == $path)
  202.             $numRemoved++;
  203.         else if ($numRemoved != 0)
  204.             for ($j = 0; $j < $numElements; $j++)
  205.                 $pluginManagerList[($i - $numRemoved) * $numElements + $j] =
  206.                     $pluginManagerList[$i * $numElements + $j];
  207.     $pluginListSize -= $numRemoved;
  208.     return $numRemoved;
  209. }
  210.  
  211. proc int isPathInSearchPath( string $path ) 
  212. //
  213. //  Procedure Name:
  214. //      isPathInSearchPath
  215. //
  216. //  Description:
  217. //      determines if the given path is in our plugin search path
  218. //
  219. //  Return Value:
  220. //      whether it is in the path
  221. //
  222. {
  223.     global string $verifiedPluginPath[];
  224.     for ($nextPath in $verifiedPluginPath) {
  225.         if ( $path == $nextPath ) {
  226.             return true;
  227.         }
  228.     }
  229.     return false;
  230. }
  231.  
  232. proc int isPluginInUI( string $path ) 
  233. //
  234. //  Procedure Name:
  235. //      isPluginInUI
  236. //
  237. //  Description:
  238. //      determines if the given plugin is listed in our UI already
  239. //
  240. //  Return Value:
  241. //      whether it is in the UI
  242. //
  243. {
  244.     global int $pluginListSize;
  245.     string $name = `pluginInfo -query -name $path`;
  246.  
  247.     for ($i = 0; $i < $pluginListSize; ++$i) {
  248.         string $plugPath = pluginListEntry( $i, "path" );
  249.         if ( `pluginInfo -query -registered $plugPath` ) {
  250.             string $plugName = `pluginInfo -query -name $plugPath`;
  251.             if ( $name == $plugName ) {
  252.                 return true;
  253.             }
  254.         }
  255.     }
  256.     return false;
  257. }
  258.  
  259. proc addSinglePlugin( string $path, string $parent )
  260. //
  261. //  Procedure Name:
  262. //      addSinglePlugin
  263. //
  264. //  Description:
  265. //      adds a single plugin, creating the widgets
  266. //
  267. { 
  268.     // Make sure the path is using forward slashes regardless of the platform
  269.     $path = convert($path);
  270.     setParent $parent; 
  271.     string $name = getFile( $path );
  272.  
  273.     int $i = appendPluginListEntry( $path, "", "", "" );
  274. //    rowLayout -nc 4 -cl1 "left"
  275. //        -columnWidth4 125 70 105 25
  276. //        -adjustableColumn 1
  277. //        -columnAlign 4 "center";
  278.     text -l $name ("PlugNameTxt" + (string)$i);
  279.     string $loadedCheck = `checkBox -align "left" -l "loaded" 
  280.         ("plugLoadedChk" + (string)$i)`; 
  281.     string $autoBox = `checkBox -align "left" -l "auto load" 
  282.         ("plugAutoLoadChk" + (string)$i)`;
  283.     string $symButt = `symbolButton -image "info.xpm" ("plugInfoBtn" + (string)$i)`;
  284. //    string $symButt = `symbolButton -image "info.xpm" -width 25 -height 28
  285. //        ("plugInfoBtn" + (string)$i)`;
  286.  
  287.     // Store the widget name so that we can update this widget later
  288.     //
  289.     setPluginListEntry( $i, $path, $loadedCheck, $autoBox, $symButt );
  290.  
  291.     // Add callbacks to controls
  292.     //
  293.     checkBox -edit -onCommand ("waitCursor -state on; catch( `loadPlugin \""
  294.         + $path + "\"`); waitCursor -state off;") 
  295.         -offCommand  ( "unloadPluginWithCheck( \"" + $path + "\" );" ) $loadedCheck;
  296.     checkBox -edit -onCommand ("pluginInfo -edit -autoload true \""
  297.         + $path + "\";" ) -offCommand 
  298.         ("pluginInfo -edit -autoload false \"" + $path + "\";" ) $autoBox;
  299.     symbolButton -edit -command ("displayPluginInfo \"" + $path + "\";" ) $symButt; 
  300. }
  301.  
  302. proc addDirectory( string $dirName, string $parent, int $index )
  303. //
  304. //  Procedure Name:
  305. //      addDirectory
  306. //
  307. //  Description:
  308. //      adds a new directory, creating the layout widget
  309. //
  310. {
  311.     global string $pluginNewestFile[];
  312.     global int $pluginFileCount[];
  313.  
  314.     string $tempString[];
  315.  
  316.     // Create a new layout widget
  317.     //
  318.     setParent $parent;
  319.     string $dir = getFile( getDir( $dirName ) ); 
  320.  
  321.     string $frameName = "PluginFrameLyt" + (string)$index;
  322.     string $par;
  323. //    string $colName = "PluginColLyt" + (string)$index;
  324.     if (`frameLayout -exists $frameName`) {
  325. //        setParent $colName;
  326.         setParent $frameName;
  327.     } else {
  328.         string $labelStr;
  329.         $labelStr = $dirName;
  330. //        $labelStr = abbreviatePath( $dirName, 50 );
  331.         frameLayout 
  332.             -mw 10 -mh 10
  333.             -borderStyle "etchedIn"
  334.             -borderVisible true 
  335.             -collapse false -collapsable true
  336.             -label $labelStr -labelVisible true $frameName;
  337. //        columnLayout -adjustableColumn true $colName;
  338.     }
  339.     string $rowColName = "PluginRowColLyt" + (string)$index;
  340.     if(`about -mac`)
  341.     {
  342.         $par = `rowColumnLayout  -cat 1 "left" 2 -columnWidth 1 200
  343.             -columnWidth 2 70
  344.             -columnWidth 3 105 -columnWidth 4 25 -nc 4 $rowColName`;
  345.     } else {
  346.         $par = `rowColumnLayout -cal 1 "left" -columnWidth 1 125
  347.             -columnWidth 2 70
  348.             -columnWidth 3 105 -columnWidth 4 25 -nc 4 $rowColName`; 
  349.     }
  350.  
  351.     // Read the directory, retaining a file count
  352.     //
  353.     string $dirList[];
  354.     string $pattern = "*.so";
  355.     if ( `about -windows` ) {
  356.         $pattern = "*.mll";
  357.     }else if( `about -mac` ){
  358.         $pattern = "*.lib";
  359.     }
  360.     
  361.     if( `about -mac` ){
  362.         catch( $dirList = `getFileList -folder $dirName -filespec $pattern` );
  363.     }else { 
  364.         catch( $dirList = `getFileList -folder ( $dirName + "/" ) -filespec $pattern` );
  365.     }
  366.  
  367.     int $fileCount = size( $dirList );
  368.     for ( $fileName in $dirList ) {
  369.         string $path = $dirName + "/" + $fileName;
  370.         addSinglePlugin( $path, $par );
  371.     }
  372.  
  373.     int $file;
  374.     // Now find the name of the newest file for later rescans
  375.     if (`about -nt`) {
  376.         $tempString = `getFileList  -folder ($dirName + "/") -filespec "*.mll"`;
  377.     }
  378.     else if(`about -mac`) {
  379.         $tempString = `getFileList  -folder $dirName -filespec "*.lib"`;
  380.     } else {
  381.         $file = popen( ( "ls -1t \"" + $dirName + "\"/*.so 2> /dev/null" ), "r" ); 
  382.     }
  383.     //string $plug = fgetline ($file);
  384.     string $plug ;
  385.     if(`about -mac` || `about -nt`) {
  386.         if(size($tempString) == 0){
  387.             $plug = 0;
  388.         }else{
  389.             $plug = $tempString[size($tempString) -1];
  390.         }
  391.     } else {
  392.         $plug = fgetline ($file);
  393.     }
  394.     
  395.     // Strip the newline
  396.     $plug = strip( $plug );
  397.  
  398.     if (`about -nt` || `about -mac`) {
  399.          $pluginNewestFile [$index] = $dirName + "/" + $plug;
  400.     }
  401.     else {
  402.         $pluginNewestFile [$index] = $plug;
  403.     }
  404.  
  405.     if(`about -nt` || `about -irix` || `about -linux`) {
  406.         pclose $file;
  407.     }
  408.     $pluginFileCount[$index] = $fileCount;
  409. } 
  410.  
  411. proc resetGlobals ()
  412. //
  413. //  Procedure Name:
  414. //      resetGlobals
  415. //
  416. //  Description:
  417. //      Resets the plug-in manager for a fresh start. This should only be
  418. //      done if the UI is already deleted.
  419. //
  420. //  Return Value:
  421. //      the directory name
  422. //    
  423. {
  424.     global string $verifiedPluginPath[];
  425.     global int    $isPluginPathVerified;
  426.     global string $pluginWinParentWidget;
  427.     global string $pluginWinSingleParent;
  428.     global string $pluginWindowName;
  429.     global int    $pluginListSize;
  430.     global string $pluginManagerList[];
  431.     global string $pluginNewestFile[];
  432.     global int    $pluginFileCount[];
  433.  
  434.     clear $verifiedPluginPath;
  435.     $isPluginPathVerified = false;
  436.     $pluginListSize = 0;
  437.     clear $pluginManagerList;
  438.     clear $pluginNewestFile;
  439.     clear $pluginFileCount;
  440. }
  441.  
  442. proc int dirChanged (string $dirName, int $index)
  443. //
  444. //  Procedure Name:
  445. //      dirChanged
  446. //
  447. //  Description:
  448. //      Determines whether or not $dirName has changed and needs to be
  449. //      re-scanned.
  450. //
  451. //  Return Value:
  452. //      the directory name
  453. //    
  454. {
  455.     global string $pluginNewestFile[];
  456.     global int $pluginFileCount[];
  457.     string $fileList[];
  458.  
  459.     // Retrieve a list of files, sorted by date
  460.     int $file;
  461.     if (`about -nt`) {
  462.         $fileList = `getFileList  -folder ($dirName + "/") -filespec "*.mll"`;
  463.     }
  464.     else if(`about -mac`) {
  465.         $fileList = `getFileList  -folder $dirName -filespec "*.lib"`;
  466.     } else {
  467.         $file = popen( ( "ls -1t \"" + $dirName + "\"/*.so 2> /dev/null" ), "r" ); 
  468.     }
  469.  
  470.     // Retrieve the first file
  471.     //string $plug = fgetline( $file );
  472.     string $plug ;
  473.     if(`about -mac` || `about -nt`) {
  474.         $plug = $fileList[0];
  475.     } else {
  476.         $plug = fgetline( $file );
  477.     }
  478.     
  479.     // Strip the newline
  480.     $plug = strip( $plug );
  481.  
  482.     if ( `about -nt` || `about -mac` )
  483.         $plug = $dirName + "/" + $plug;
  484.  
  485.     // Now count the number of files - a double check
  486.     int $count = 0;
  487.     int $isDirty = 0;
  488.     
  489.     if (`about -mac` || `about -nt` ) {
  490.         string  $singleFile;
  491.         for ($singleFile in $fileList) {
  492.             if(size($singleFile) > 1){
  493.                 $count++;
  494.                 $plug = $dirName + "/" + $singleFile;
  495.                 
  496.                 // Check if every plugin is present in the pluginListEntry
  497.                 // If not set the dirty flag so that the list is regenerated
  498.                 
  499.                 global int    $pluginListSize;
  500.                 int $fileExists = 0;
  501.                 for ($i = 0; $i < $pluginListSize; $i++)
  502.                 {
  503.                     string $fileEntry = pluginListEntry ($i, "path");
  504.                     if ($plug == $fileEntry) {
  505.                         $fileExists = 1;
  506.                         break;
  507.                     }
  508.                 }
  509.  
  510.                 if ($fileExists == 0) {
  511.                     $isDirty = 1;
  512.                     break;
  513.                 }
  514.             }
  515.         }
  516.     } else {
  517.         string $line = $plug;
  518.  
  519.         while (size($line) > 1)
  520.         {
  521.             $count++;
  522.             $line = fgetline ( $file);
  523.         }
  524.         pclose $file;
  525.  
  526.         // $plug now contains the newest file in the directory. If this file
  527.         // doesn't match the newest from the last time around or the file count
  528.         // doesn't match, the directory has changed and needs to be regenerated.
  529.         // This is not the best solution to the problem, but until MEL gets a
  530.         // stat() method, it's the only way...
  531.         
  532.         if ($plug != $pluginNewestFile [$index])
  533.             $isDirty = 1;
  534.     }
  535.  
  536.     if ($count == $pluginFileCount [$index] &&
  537.          $isDirty == 0)
  538.         return false;
  539.     return true;
  540. }
  541.  
  542. proc rescanDirectory( string $dirName, string $parent, int $index)
  543. //
  544. //  Procedure Name:
  545. //      rescanDirectory
  546. //
  547. //  Description:
  548. //      rescans a directory, creating layout widgets for any new plug-ins and
  549. //      removing layout widgets for removed plug-ins
  550. {
  551.     if (dirChanged ($dirName, $index)) {
  552.         string $frame = "PluginFrameLyt" + (string) $index;
  553.         string $children[] = `frameLayout -q -childArray $frame`;
  554. //        string $par = "PluginColLyt" + (string) $index;
  555. //        string $children[] = `columnLayout -q -childArray $par`;
  556.  
  557.         string $child;
  558.  
  559.         for ($child in $children)
  560.             deleteUI $child;
  561.         removePluginListEntries ($dirName);
  562.         addDirectory ($dirName, $parent, $index);
  563.     }    
  564. }
  565.  
  566. //////////////////////
  567. // Global Functions //
  568. //////////////////////
  569.  
  570. global proc updatePluginWin()
  571. //
  572. //  Procedure Name:
  573. //      updatePluginWin
  574. //
  575. //  Description:
  576. //      refreshes the values in the plugin window 
  577. //
  578. //  Return Value:
  579. //      None
  580. //
  581. {
  582.     global string $verifiedPluginPath[];
  583.     global int    $isPluginPathVerified;
  584.     global string $pluginWinParentWidget;
  585.     global string $pluginWinSingleParent;
  586.     global string $pluginWindowName;
  587.     global int    $pluginListSize;
  588.  
  589.     // Make sure the window exists
  590.     //
  591.     if (!`window -exists $pluginWindowName`) {
  592.         return;
  593.     }
  594.  
  595.     int $buildUI = false;
  596.  
  597.  
  598.     // Make sure that our path array is set up
  599.     //
  600.     if ( !$isPluginPathVerified ) {
  601.         // We will read the environment variable and check to see that all paths
  602.         // are valid
  603.         //
  604.         string $pathEnvVar = getenv("MAYA_PLUG_IN_PATH");
  605.  
  606.         string $pathArray[];
  607.         if (`about -nt` || `about -mac`) {
  608.             tokenize( $pathEnvVar, ";", $pathArray );
  609.         }
  610.         else {
  611.             tokenize( $pathEnvVar, ":", $pathArray );
  612.         }
  613.         
  614.         // Check that the paths are valid
  615.         //
  616.         int $index = 0;
  617.         for ($path in $pathArray) {
  618.             string $oldPath = `pwd`;
  619.             // Expand the environment variables in the path
  620.             //
  621.             string $expandedPath;
  622.             if (`about -nt` || `about -mac`) {
  623.                 $expandedPath = $path;
  624.             }
  625.             else {
  626.                 $expandedPath = system( "echo " + $path );
  627.                 // Strip the newline
  628.                 $expandedPath = strip ($expandedPath);
  629.             }
  630.             if ( 0 == `chdir $expandedPath` ) {
  631.                 // Get the expanded path in standard form
  632.                 //
  633.                 if(`about -mac`) {
  634.                     $verifiedPluginPath[$index] = $expandedPath;
  635.                 } else {
  636.                     $verifiedPluginPath[$index] =`pwd`;
  637.                 }
  638.                 chdir $oldPath;
  639.                  ++$index;
  640.             }
  641.         } 
  642.         $buildUI = true;
  643.         $isPluginPathVerified = 1;
  644.     } 
  645.  
  646.     if ( $buildUI ) { 
  647.         // The UI hasn't been built yet
  648.         //
  649.         waitCursor -state on;
  650.  
  651.         int $index = 1;
  652.         for ( $path in $verifiedPluginPath ) {
  653.             addDirectory( $path, $pluginWinParentWidget, $index );
  654.             $index++;
  655.         }
  656.         // Put in the misc section
  657.         //
  658.         setParent $pluginWinParentWidget;
  659.         frameLayout 
  660.             -borderStyle "etchedIn"
  661.             -borderVisible true -collapse false -collapsable true 
  662.             -label "Other Registered Plugins" -labelVisible true
  663.             -mw 10 -mh 10
  664.             "PluginFrameLytMisc";
  665.         if(`about -mac`) {
  666.             $pluginWinSingleParent = `rowColumnLayout  -cat 1 "left" 2 -columnWidth 1 200 
  667.                 -columnWidth 2 70 -columnWidth 3 105 -columnWidth 4 25 -nc 4
  668.                 PluginRowColLytMisc`;
  669.         } else {
  670.             $pluginWinSingleParent = `rowColumnLayout -cal 1 "left" -columnWidth 1 125 
  671.                 -columnWidth 2 70 -columnWidth 3 105 -columnWidth 4 25 -nc 4
  672.                 PluginRowColLytMisc`;
  673.         }
  674. //        $pluginWinSingleParent = `columnLayout -adjustableColumn true
  675. //          PluginColLytMisc`;
  676.  
  677.         waitCursor -state off;
  678.     } 
  679.     else {
  680.         int $index = 1;
  681.         for ( $path in $verifiedPluginPath ) {
  682.             rescanDirectory( $path, $pluginWinParentWidget, $index );
  683.             $index++;
  684.         }
  685.     }
  686.  
  687.     // Make sure that all registered plugins appear in UI
  688.     // 
  689.     string $knownPlugins[] = `pluginInfo -q -listPlugins`;
  690.  
  691.     string $dir; 
  692.     for ( $plugin in $knownPlugins ) {  
  693.         $path = `pluginInfo -query -path $plugin`;
  694.         $dir = getDir( $path );
  695.         if ( !isPathInSearchPath( $dir ) ) {
  696.             // We don't know this path, so this is a singleton plugin
  697.             //
  698.             if ( !isPluginInUI( $plugin ) ) {
  699.                 addSinglePlugin( $path, $pluginWinSingleParent );
  700.             }
  701.         }
  702.     }
  703.  
  704.     // Now, we need to make sure that the check boxes in the UI reflect the current
  705.     // state
  706.     //
  707.     for ($i=0; $i < $pluginListSize; ++$i) {
  708.         string $path = pluginListEntry( $i, "path" );
  709.         string $loadedWidgName = pluginListEntry( $i, "loadedWidget" );
  710.         string $autoWidgName = pluginListEntry( $i, "autoloadWidget" );
  711.         string $infoWidgName = pluginListEntry( $i, "infoWidget" );
  712.  
  713.         int $isLoaded = `pluginInfo -query -loaded $path`; 
  714.  
  715.         if ( $isLoaded != ( `checkBox -query -value $loadedWidgName` ) ) {
  716.             checkBox -edit -value $isLoaded $loadedWidgName;
  717.         }             
  718.         // Check autoload status
  719.         //
  720.         int $auto = `pluginInfo -query -autoload $path`;
  721.         checkBox -edit -value $auto $autoWidgName;
  722.  
  723.          if ( `pluginInfo -query -registered $path` ) { 
  724.             // We have valid info for the plugin
  725.             // 
  726.             symbolButton -edit -enable 1 $infoWidgName; 
  727.         } else { 
  728.             // We don't have information about the given plugin in our database
  729.             // as it has never been loaded.  Therefore, we will dim the info button
  730.             // 
  731.             symbolButton -edit -enable 0 $infoWidgName;
  732.         }
  733.     }
  734. } 
  735.  
  736. global proc int loadPluginCallback( string $theFile, string $fileType )
  737. //
  738. //  Procedure Name:
  739. //      loadPluginCallback
  740. //
  741. //  Description:
  742. //      this is used by the file browser for actually loading the plugin, and
  743. //      also remembers the last directory from which a plug-in was loaded.
  744. //
  745. //  Return Value:
  746. //      None
  747. //    
  748. {
  749.     global string $defaultPluginBrowseDir;
  750.     $defaultPluginBrowseDir = `getDir $theFile`;
  751.     // Set the file rule - this makes sure that future calls to browse
  752.     // start from the same place
  753.     if ( catch( `loadPlugin $theFile` ) ) {
  754.          warning ( "Could not load " + $theFile + " as a plug-in" );
  755.          return false;
  756.      } 
  757.     return true;
  758. }
  759.  
  760. global proc browsePlugin() 
  761. //
  762. //  Procedure Name:
  763. //      browsePlugin
  764. //
  765. //  Description:
  766. //      this is a UI equivalent to loadPlugin.  It puts up a file requestor. 
  767. //      It keeps track of the directory it used last and maintains it
  768. //      separately from the workspace directory. It starts in the user's home
  769. //      directory.
  770. //
  771. //  Return Value:
  772. //      None
  773. //    
  774. {  
  775.     global string $defaultPluginBrowseDir;
  776.     global string $gDefaultFileBrowserDir;
  777.  
  778.     // Note: every time Maya is restarted, the file rule is reset. This is
  779.     // intentional - the default location is Maya's starting point. Change
  780.     // this if the default changes.
  781.     if ($defaultPluginBrowseDir == "") {
  782.             global string $verifiedPluginPath[];
  783.             if (size ($verifiedPluginPath) > 0)
  784.                 $defaultPluginBrowseDir =  $verifiedPluginPath[0];
  785.             else
  786.                 $defaultPluginBrowseDir =  pwd ();
  787.     }
  788.     $gDefaultFileBrowserDir = $defaultPluginBrowseDir;
  789.  
  790.     string $prevDir = `workspace -query -directory`;
  791.     workspace -directory $defaultPluginBrowseDir;
  792.     fileBrowser ( "loadPluginCallback", "Load Plug-in", "plug-in", 0 );
  793.     workspace -directory $prevDir;
  794. }
  795.  
  796. global proc displayPluginInfo( string $path ) 
  797. //
  798. //  Procedure Name:
  799. //      displayPluginInfo
  800. //
  801. //  Description:
  802. //      opens a window and displays information about the given plugin
  803. //
  804. //  Return Value:
  805. //      None
  806. //
  807. {
  808.     global string $pluginInfoWinName;
  809.     global string $pluginInfoWinPath;
  810.     global string $pluginInfoWinVendor;
  811.     global string $pluginInfoWinAutoLoad;
  812.     global string $pluginInfoWinLoaded;
  813.     global string $pluginInfoWinAPIVerson;
  814.     global string $pluginInfoWinVerson;
  815.     global string $pluginInfoWinFeatures; 
  816.     int    $numHtCount = 0;
  817.  
  818.     string $name = `pluginInfo -query -name $path`;
  819.     if ( catch( $path = `pluginInfo -query -path $name` ) ) {
  820.         warning "Plug-in information not in database";
  821.     }
  822.  
  823.     string $winName = "PluginInfoWin";
  824.  
  825.     if (!`window -exists $winName`) {
  826.         window -t "Plug-in Information"  -wh 340 280 $winName;
  827.         formLayout windowLyt;
  828.             scrollLayout -cr true scrollLayout;
  829.                 formLayout scrollWindowLyt; 
  830.                     columnLayout -adjustableColumn true infoLyt;
  831.                         rowLayout -nc 2 -cw2 100 340 -adjustableColumn 2;
  832.                         text -label "Name: " -align "left" nameTxt;
  833.                         $pluginInfoWinName = `text -align "left" nameValTxt`;
  834.                         setParent ..;
  835.  
  836.                         rowLayout -nc 2 -cw2 100 340 -adjustableColumn 2;
  837.                         text -label "Path: " -align "left" pathTxt;
  838.                         $pluginInfoWinPath = `text -align "left" pathValTxt`;
  839.                         setParent ..;
  840.  
  841.                         rowLayout -nc 2 -cw2 100 340 -adjustableColumn 2;
  842.                         text -label "Vendor: " -align "left" vendTxt; 
  843.                         $pluginInfoWinVendor = `text -align "left" vendValTxt`;
  844.                         setParent ..;
  845.  
  846.                         rowLayout -nc 2 -cw2 100 340 -adjustableColumn 2;
  847.                         text -label "Plug-in Version: " -align "left" versionTxt; 
  848.                         $pluginInfoWinVerson = `text -align "left" versValTxt`;
  849.                         setParent ..;
  850.  
  851.                         rowLayout -nc 2 -cw2 100 340 -adjustableColumn 2;
  852.                         text -label "For API Version: " -align "left" apiVersionTxt; 
  853.                         $pluginInfoWinAPIVerson = `text -align "left" apiVersValTxt`;
  854.                         setParent ..;
  855.  
  856.                         rowLayout -nc 2 -cw2 100 340 -adjustableColumn 2;
  857.                         text -label "Auto Load: " -align "left" autoTxt; 
  858.                         $pluginInfoWinAutoLoad = `text -align "left" autoValTxt`; 
  859.                         setParent ..;
  860.  
  861.                         rowLayout -nc 2 -cw2 100 340 -adjustableColumn 2;
  862.                         text -label "Is Loaded: " -align "left" isLoadedTxt; 
  863.                         $pluginInfoWinLoaded = `text -align "left" isLoadedValTxt`; 
  864.                         setParent ..;
  865.                     setParent ..;
  866.             
  867.                     frameLayout -borderVisible true
  868.                         -collapsable false -label "Plug-in Features" 
  869.                         -labelVisible true pluginFeaturesLyt;
  870.                         if(`about -mac`) {
  871.                             $pluginInfoWinFeatures = `textField  featuresTxt`;
  872.                         } else {
  873.                             $pluginInfoWinFeatures = `text -align "left" featuresTxt`; 
  874.                         }
  875.                     setParent ..;
  876.  
  877.                 formLayout -e    -af infoLyt "left" 0
  878.                                 -af infoLyt "right" 0 
  879.                                 -af infoLyt "top" 0
  880.                                 scrollWindowLyt; 
  881.  
  882.                 formLayout -e    -af pluginFeaturesLyt "left" 0 
  883.                                 -af pluginFeaturesLyt "right" 0
  884.                                 -af pluginFeaturesLyt "bottom" 0 
  885.                                 -ac infoLyt "bottom" 0 pluginFeaturesLyt
  886.                                 scrollWindowLyt;  
  887.                 setParent ..;
  888.             setParent ..;
  889.  
  890.         $closeInfoBtn = `button -l "Close" closeInfoBtn`;
  891.  
  892.         formLayout -e -af $closeInfoBtn "left" 5
  893.                       -af $closeInfoBtn "right" 5
  894.                       -af $closeInfoBtn "bottom" 5
  895.                       -an $closeInfoBtn "top"
  896.                       windowLyt;
  897.  
  898.         formLayout -e -af scrollLayout "top" 0
  899.                       -af scrollLayout "left" 0
  900.                       -af scrollLayout "right" 0
  901.                       -ac scrollLayout "bottom" 5 $closeInfoBtn
  902.                       windowLyt;
  903.  
  904.         button -edit -command "deleteUI PluginInfoWin" $closeInfoBtn;
  905.  
  906.         setParent ..; // close the formLayout
  907.     }  
  908.  
  909.     // Update all of the fields
  910.     //
  911.     text -edit -label $name $pluginInfoWinName;
  912.     text -edit -label $path $pluginInfoWinPath;
  913.     text -edit -label `pluginInfo -query -vendor $name` $pluginInfoWinVendor;
  914.     text -edit -label `pluginInfo -query -version $name` $pluginInfoWinVerson;
  915.     text -edit -label `pluginInfo -query -apiVersion $name` $pluginInfoWinAPIVerson;
  916.     if ( `pluginInfo -query -autoload $name` ) {
  917.         text -edit -label "Yes" $pluginInfoWinAutoLoad;
  918.     } else {
  919.         text -edit -label "No" $pluginInfoWinAutoLoad; 
  920.     } 
  921.     if ( `pluginInfo -query -loaded $name` ) {
  922.         text -edit -label "Yes" $pluginInfoWinLoaded;
  923.     } else {
  924.         text -edit -label "No" $pluginInfoWinLoaded; 
  925.     } 
  926.  
  927.     if(`about -mac`){
  928.         $numHtCount += 1;
  929.     }
  930.     // Build list of plugin features starting with commands
  931.     //
  932.     string $featureStr = "";
  933.     string $commands[] = `pluginInfo -query -command $name`;
  934.     if ( size( $commands ) > 0 ) {
  935.         $featureStr = "  Commands:\n";
  936.         if(`about -mac`) {
  937.             $numHtCount += 1; 
  938.         }
  939.         if(`about -mac`) {
  940.             $numHtCount += size( $commands );
  941.         }        
  942.         for ( $command in $commands ) {
  943.             $featureStr = ( $featureStr + "      " + $command ); 
  944.             if ( $command != $commands[ size( $commands ) - 1 ] ) {
  945.                 $featureStr = $featureStr + "\n";
  946.             }
  947.         } 
  948.     }
  949.  
  950.     // Build list of context commands
  951.     //
  952.     string $tools[] = `pluginInfo -query -tool $name`; 
  953.     if ( size( $tools ) > 0 ) {
  954.         if ( $featureStr != "" ) {
  955.             $featureStr = $featureStr + "\n\n";
  956.             if(`about -mac`){
  957.                     $numHtCount += 2;
  958.             }
  959.         } 
  960.         $featureStr = $featureStr + "  Tools:\n";
  961.         if(`about -mac`) {
  962.                     $numHtCount += 1;
  963.         }
  964.         if(`about -mac`) {
  965.             $numHtCount += size( $tools );
  966.         }    
  967.         for ( $tool in $tools ) {
  968.             $featureStr = ( $featureStr + "      " + $tool );  
  969.             if ( $tool != $tools[ size( $tools ) - 1 ] ) {
  970.                 $featureStr = $featureStr + "\n";
  971.             }
  972.         }
  973.     } 
  974.  
  975.     // Build list of dependency nodes
  976.     //
  977.     string $nodes[] = `pluginInfo -query -dependNode $name`;
  978.     if ( size( $nodes ) > 0 ) { 
  979.         if ( $featureStr != "" ) {
  980.             $featureStr = $featureStr + "\n\n";
  981.             if(`about -mac`) {
  982.                     $numHtCount += 2;
  983.             }
  984.         } 
  985.         $featureStr = $featureStr + "  Dependency Nodes:\n";
  986.         if(`about -mac`){
  987.             $numHtCount += 1;
  988.         }
  989.         if(`about -mac`) {
  990.             $numHtCount += size( $nodes );
  991.         }
  992.         for ( $node in $nodes ) {
  993.             $featureStr = ( $featureStr + "      " + $node );  
  994.             if ( $node != $nodes[ size( $nodes ) - 1 ] ) {
  995.                 $featureStr = $featureStr + "\n";
  996.             }
  997.         }
  998.     } 
  999.  
  1000.     // Build list of dependency graph data types
  1001.     //
  1002.     string $data[] = `pluginInfo -query -data $name`; 
  1003.     if ( size( $data ) > 0 ) { 
  1004.         if ( $featureStr != "" ) {
  1005.             $featureStr = $featureStr + "\n\n";
  1006.             if(`about -mac`) {
  1007.                 $numHtCount += 2;
  1008.             }
  1009.         } 
  1010.         $featureStr = $featureStr + "  Dependency Graph Data Types:\n";
  1011.         if(`about -mac`) {
  1012.             $numHtCount += 1;
  1013.         }
  1014.         if(`about -mac`) {
  1015.             $numHtCount += size( $data );
  1016.         }    
  1017.         for ( $datum in $data ) {
  1018.             $featureStr = ( $featureStr + "      " + $datum );  
  1019.             if ( $datum != $data[ size( $data ) - 1 ] ) {
  1020.                 $featureStr = $featureStr + "\n";
  1021.             }
  1022.         }
  1023.     }
  1024.  
  1025.     // Build list of file translators
  1026.     //
  1027.     string $translators[] = `pluginInfo -query -translator $name`;
  1028.     if ( size( $translators ) > 0 ) {
  1029.         if ( $featureStr != "" ) {
  1030.             $featureStr = $featureStr + "\n\n";
  1031.             if(`about -mac`) {
  1032.                 $numHtCount += 2;
  1033.             }
  1034.         }
  1035.         $featureStr = $featureStr + "  File Translators:\n";
  1036.         if(`about -mac`) {
  1037.             $numHtCount += 1;
  1038.         }
  1039.         if(`about -mac`) {
  1040.             $numHtCount += size( $translators );
  1041.         }    
  1042.         for ( $translator in $translators ) {
  1043.             $featureStr = ( $featureStr + "      " + $translator );
  1044.             if ( $translator != $translators[ size( $translators ) - 1 ] ) {
  1045.                 $featureStr = $featureStr + "\n";
  1046.             }
  1047.         }
  1048.     }
  1049.  
  1050.     // Build list of ik solvers
  1051.     //
  1052.     string $ikSolvers[] = `pluginInfo -query -iksolver $name`;
  1053.     if ( size( $ikSolvers ) > 0 ) {
  1054.         if ( $featureStr != "" ) {
  1055.             $featureStr = $featureStr + "\n\n";
  1056.             if(`about -mac`){
  1057.                     $numHtCount += 2;
  1058.             }
  1059.         }
  1060.         $featureStr = $featureStr + "  Ik Solvers:\n";
  1061.         if(`about -mac`){
  1062.                     $numHtCount += 1;
  1063.         }
  1064.         if(`about -mac`)
  1065.             $numHtCount += size( $ikSolvers );
  1066.             
  1067.         for ( $ikSolver in $ikSolvers ) {
  1068.             $featureStr = ( $featureStr + "      " + $ikSolver );
  1069.             if ( $ikSolver != $ikSolvers[ size( $ikSolvers ) - 1 ] ) {
  1070.                 $featureStr = $featureStr + "\n";
  1071.             }
  1072.         }
  1073.     }
  1074.  
  1075.     // Build list of input devices
  1076.     //
  1077.     string $devices[] = `pluginInfo -query -device $name`;
  1078.     if ( size( $devices ) > 0 ) {
  1079.         if ( $featureStr != "" ) {
  1080.             $featureStr = $featureStr + "\n\n";
  1081.             if(`about -mac`){
  1082.                     $numHtCount += 2;
  1083.             }
  1084.         }
  1085.         $featureStr = $featureStr + "  Input Devices:\n";
  1086.         if(`about -mac`){
  1087.                     $numHtCount += 1;
  1088.         }
  1089.         if(`about -mac`)
  1090.             $numHtCount += size( $devices );
  1091.             
  1092.         for ( $device in $devices ) {
  1093.             $featureStr = ( $featureStr + "      " + $device );
  1094.             if ( $device != $devices[ size( $devices ) - 1 ] ) {
  1095.                 $featureStr = $featureStr + "\n";
  1096.             }
  1097.         }
  1098.     }
  1099.  
  1100.     // Build list of drag and drop behaviors
  1101.     //
  1102.     string $behaviors[] = `pluginInfo -query -dragAndDropBehavior $name`;
  1103.     if ( size( $behaviors ) > 0 ) {
  1104.         if ( $featureStr != "" ) {
  1105.             $featureStr = $featureStr + "\n\n";
  1106.         }
  1107.         $featureStr = $featureStr + "  Drag and Drop Behaviors:\n";
  1108.         for ( $behavior in $behaviors ) {
  1109.             $featureStr = ( $featureStr + "      " + $behavior );
  1110.             if ( $behavior != $behaviors[ size( $behaviors ) - 1 ] ) {
  1111.                 $featureStr = $featureStr + "\n";
  1112.             }
  1113.         }
  1114.     }
  1115.  
  1116.     if(`about -mac`) {
  1117.         $numHtCount += 1;
  1118.     }
  1119.  
  1120.     if(`about -mac`) {
  1121.         int    $totalHeight = $numHtCount * 15;
  1122.         
  1123.         textField -edit -text $featureStr  $pluginInfoWinFeatures;
  1124.         textField -edit  -h $totalHeight  $pluginInfoWinFeatures;
  1125.         textField -edit  -ed false  $pluginInfoWinFeatures;
  1126.     } else {
  1127.         text -edit -label $featureStr $pluginInfoWinFeatures;
  1128.     }
  1129.  
  1130.     showWindow $winName;
  1131. }
  1132.  
  1133. global proc pluginWin()  
  1134. //
  1135. //  Procedure Name:
  1136. //      pluginWin
  1137. //
  1138. //  Description:
  1139. //      opens up a window which allows the user to load/unload plugins.
  1140. //      re-scans when called with an open window
  1141. //
  1142. //  Return Value:
  1143. //      None
  1144. //    
  1145. {   
  1146.     global int    $isPluginPathVerified;
  1147.     global string $verifiedPluginPath[];
  1148.     global string $pluginManagerList[];
  1149.  
  1150.     global string $pluginWindowName = "pluginManagerWindow";
  1151.     global string $pluginWinParentWidget;
  1152.  
  1153.     global int      $pluginWinCallbackInstalled = false;
  1154.  
  1155.     string $browseBtn;
  1156.  
  1157.     if (!`window -exists $pluginWindowName`) { 
  1158.         // We have to build the window from scratch, so we will rescan
  1159.         // the directories
  1160.         //
  1161.         resetGlobals;
  1162.  
  1163.         // Create the UI
  1164.         //
  1165.         if(`about -mac`) {
  1166.             window -t "Plug-in Manager" -in "Plug-ins"
  1167.             -menuBar true
  1168.             -retain -wh 450 411 $pluginWindowName;
  1169.         } else {
  1170.         window -t "Plug-in Manager" -in "Plug-ins"
  1171.             -menuBar true
  1172.             -retain -wh 384 411 $pluginWindowName;
  1173.         }
  1174.         menu -label "Help" -helpMenu true;
  1175.             menuItem -label "Help on Plug-in Manager..."
  1176.                 -enableCommandRepeat false
  1177.                 -command "showHelp PluginWindow";
  1178.             
  1179.         // This form layout becomes the default layout for the window
  1180.         //
  1181.         formLayout windowLyt; 
  1182.             tabLayout -cr true -scr true -tv false scrollLyt; 
  1183.                 // The following layout will get deleted a rebuilt if new
  1184.                 // paths or plugins are loaded
  1185.                 //
  1186.                 $pluginWinParentWidget = `columnLayout -adj true parentLyt`;
  1187.                 setParent ..; 
  1188.             setParent ..;
  1189.             $browseBtn = `button -l "Browse" browseBtn`; 
  1190.             $closeBtn = `button -l "Close" closeBtn`; 
  1191.  
  1192.         // Arrange controls in the form
  1193.         //
  1194.         // Attach button 
  1195.         formLayout -e
  1196.             -af $browseBtn "left" 5
  1197.             -ap $browseBtn "right" 3 50 
  1198.             -af $browseBtn "bottom" 5
  1199.             -an $browseBtn "top"
  1200.  
  1201.             -ap $closeBtn "left" 2 50
  1202.             -af $closeBtn "right" 5
  1203.             -af $closeBtn "bottom" 5
  1204.             -an $closeBtn "top"
  1205.             windowLyt;
  1206.  
  1207.         // Attach scroll layout 
  1208.         formLayout -e 
  1209.             -af scrollLyt "top" 0 
  1210.             -af scrollLyt "left" 0 
  1211.             -af scrollLyt "right" 0 
  1212.             -ac scrollLyt "bottom" 5 $browseBtn 
  1213.             windowLyt;
  1214.  
  1215.         button -edit -command "browsePlugin" $browseBtn;
  1216.         button -edit -command "window -e -vis 0 pluginManagerWindow" $closeBtn;
  1217.  
  1218.         setParent ..;
  1219.  
  1220.         // Tell updatePluginWin the check path and build UI
  1221.         //
  1222.         $isPluginPathVerified = 0;
  1223.  
  1224.         // Add a callback to the plugin database so that the window gets
  1225.         // updated
  1226.         //
  1227.         if ( !$pluginWinCallbackInstalled ) {
  1228.             pluginInfo -changedCommand "updatePluginWin();";
  1229.             $pluginWinCallbackInstalled = true;
  1230.         }
  1231.  
  1232.         updatePluginWin();
  1233.     }
  1234.     else
  1235.         updatePluginWin();
  1236.     showWindow $pluginWindowName;
  1237. } 
  1238.  
  1239. global proc unloadPluginWithCheck( string $path )
  1240. //
  1241. //  Description:
  1242. //      unload the plugin, or warn if it is being used
  1243. //
  1244. { 
  1245.     global string $pluginWindowName;
  1246.     if ( `pluginInfo -query -unloadOk $path` ) {
  1247.         waitCursor -state on;
  1248.         unloadPlugin `pluginInfo -query -name $path`; 
  1249.         waitCursor -state off;
  1250.     } else {
  1251.         string $serviceList[] = `pluginInfo -query -serviceDescriptions $path`;
  1252.         string $services = "";
  1253.         for ( $service in $serviceList  ){
  1254.             $services = ( $services + "- " + $service + "\n" );
  1255.         }
  1256.         string $pluginName = `pluginInfo -query -name $path`;
  1257.         int $isUnlimitedPlugin = false;
  1258.         string $result;
  1259.         if(!strcmp($pluginName,"Fur") || !strcmp($pluginName,"CpClothPlugin") || !strcmp($pluginName,"mayalive"))
  1260.         {
  1261.             $isUnlimitedPlugin = true;
  1262.             $result = `confirmDialog -ma left -title "Plug-in In Use Warning"
  1263.             -message ( "Services provided by this plug-in are\n" + 
  1264.                        "currently in use.\n\n" +
  1265.                        "Forcefully unloading this plug-in opens\n" +
  1266.                        "the \"File->Save Scene As...\" dialog box to save this scene\n"+
  1267.                        "and creates a new empty scene.\n\n"  +
  1268.                           "The following services are in use:\n" + $services ) 
  1269.             -button "Force" -button "Cancel" -defaultButton "Cancel"
  1270.             -cancelButton "Cancel" -dismissString "Cancel"
  1271.             -parent $pluginWindowName`;
  1272.         }
  1273.         else
  1274.         {
  1275.             $result = `confirmDialog -ma left -title "Plug-in In Use Warning"
  1276.                 -message ( "Services provided by this plug-in are\n" + 
  1277.                            "currently in use.\n\n" +
  1278.                            "Unloading this plug-in may cause problems\n" +
  1279.                            "with your scene.  To unload this plug-in\n" +
  1280.                            "safely, remove all objects that reference\n" +
  1281.                            "the plug-in and flush the undo queue either\n" +
  1282.                            "with \"file -new\" or the \"flushUndo\" command.\n\n" +
  1283.                            "The following services are in use:\n" + $services ) 
  1284.                 -button "Force" -button "Cancel" -defaultButton "Cancel"
  1285.                 -cancelButton "Cancel" -dismissString "Cancel"
  1286.                 -parent $pluginWindowName`;
  1287.         }
  1288.         if ( $result == "Force" ) {
  1289.             if( $isUnlimitedPlugin == true)
  1290.             {
  1291.                 SaveSceneAs;
  1292.                 waitCursor -state on;
  1293.                 if ( !strcmp($pluginName,"mayalive") ) {
  1294.                     global int $liveUnloading;
  1295.                     $liveUnloading = 1;
  1296.                     mlResetAllDeletable;
  1297.                     file -f -new;
  1298.                      evalDeferred -lp "unloadPlugin -f mayalive";
  1299.                 }
  1300.                 else {
  1301.                     file -f -new;
  1302.                     unloadPlugin -force `pluginInfo -query -name $path`;
  1303.                 }       
  1304.                 waitCursor -state off;            
  1305.             }
  1306.             else
  1307.             {
  1308.                 waitCursor -state on;
  1309.                 unloadPlugin -force `pluginInfo -query -name $path`;
  1310.                 waitCursor -state off;
  1311.             }
  1312.         }
  1313.         else {
  1314.             // This will turn the check box back on
  1315.             updatePluginWin();
  1316.         }
  1317.     }
  1318. }
  1319.